home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 092 - EBU.dsk / GAMES / LEMONAIDE.STAND.bas < prev    next >
BASIC Source File  |  2019-02-17  |  15KB  |  152 lines
  1. 1  GOSUB 781: GOSUB 801: GOTO 101
  2. 11  COLOR= 15: IF  RND(K1) >KP  THEN 51
  3. 21 X =  RND(K1) *K5 +K8:Y = 5:I =  RND(K1) *K4 +K7: VLIN Y,I AT X: FOR J = 1 TO 6:Y = I +K1:I = I +K3 + RND(K1) *K5:X = X +K1 -K2 *( RND(K1) >KP): IF I >KTP  AND X >KL  THEN X = X -K2
  4. 31  IF I >KB  THEN 91
  5. 41  IF I <KB  THEN  VLIN Y,I AT X: NEXT : RETURN 
  6. 51 X =  RND(K1) *K8 +26:Y = K7:I =  RND(K1) *K5 +K7: VLIN Y,I AT X
  7. 61 Y = I +K1:I = I +K3 + RND(K1) *K5:X = X +K1 -K2 *( RND(K1) >KP): IF X <KR  THEN X = X +K2
  8. 71  IF I >KB  THEN 91
  9. 81  VLIN Y,I AT X: GOTO 61
  10. 91  RETURN 
  11. 101  DIM A(30),L(30),H(30),B(30),S(30),P(30),G(30):P9 = 10:S3 = .15:S2 = 30:A2 = 2.00:C9 = .5:C2 = 1: GOSUB 921: FOR I = 1 TO N:B(I) = 0:A(I) = A2: NEXT : IF A$ = "Y"  THEN  GOSUB 971: GOTO 121
  12. 111  GOSUB 1021
  13. 121 SC =  RND(1): IF SC <.6  THEN SC = 2: GOTO 151
  14. 131  IF SC <.8  THEN SC = 10: GOTO 151
  15. 141 SC = 7
  16. 151  IF D <3  THEN SC = 2
  17. 161  GOSUB 1131: TEXT : HOME :D = D +1: PRINT "ON DAY ";D;", THE COST OF LEMONADE IS ";:C = 2: IF D >2  THEN C = 4
  18. 171  IF D >6  THEN C = 5
  19. 181  PRINT "$.0";C: PRINT :C1 = C *.01:R1 = 1: IF D < >3  THEN 201
  20. 191  PRINT "(YOUR MOTHER QUIT GIVING YOU FREE SUGAR)"
  21. 201  IF D < >7  THEN 221
  22. 211  PRINT "(THE PRICE OF LEMONADE MIX JUST WENT UP)"
  23. 221  IF D >2  THEN 601
  24. 231  PRINT : POKE 34, PEEK(37): FOR I = 1 TO N:A(I) = A(I) +.000000001
  25. 241 G(I) = 1:H(I) = 0:STI = A(I): GOSUB 731: PRINT "LEMONADE STAND ";I; TAB( 26);"ASSETS ";STI$: PRINT : IF B(I) = 0  THEN 261
  26. 251  PRINT "YOU ARE BANKRUPT, NO DECISIONS": PRINT "FOR YOU TO MAKE.": GOSUB 1461: GOTO 441
  27. 261  PRINT "HOW MANY GLASSES OF LEMONADE DO YOU": PRINT "WISH TO MAKE ";: INPUT IN$:L(I) =  VAL(IN$): IF L(I) <0  OR L(I) >1000  THEN 281
  28. 271  GOTO 291
  29. 281  PRINT "COME ON, LET'S BE REASONABLE NOW!!!": PRINT "TRY AGAIN": GOTO 261
  30. 291  IF L(I) < > INT(L(I))  THEN 281
  31. 301  IF L(I) *C1 < = A(I)  THEN 321
  32. 311  PRINT "THINK AGAIN!!!  YOU HAVE ONLY ";STI$: PRINT "IN CASH AND TO MAKE ";L(I);" GLASSES OF": PRINT "LEMONADE YOU NEED $";L(I) *C1;" IN CASH.": GOTO 261
  33. 321  PRINT : PRINT "HOW MANY ADVERTISING SIGNS (";S3 *100;" CENTS": PRINT "EACH) DO YOU WANT TO MAKE ";: INPUT IN$:S(I) =  VAL(IN$): IF S(I) <0  OR S(I) >50  THEN 341
  34. 331  GOTO 351
  35. 341  PRINT "COME ON, BE REASONABLE!!! TRY AGAIN.": GOTO 321
  36. 351  IF S(I) < > INT(S(I))  THEN 341
  37. 361  IF S(I) *S3 < = A(I) -L(I) *C1  THEN 381
  38. 371  PRINT :STI = A(I) -L(I) *C1: GOSUB 731: PRINT "THINK AGAIN, YOU HAVE ONLY ";STI$: PRINT "IN CASH LEFT AFTER MAKING YOUR LEMONADE.": GOTO 321
  39. 381  PRINT : PRINT "WHAT PRICE (IN CENTS) DO YOU WISH TO": PRINT "CHARGE FOR LEMONADE ";: INPUT IN$:P(I) =  VAL(IN$): IF P(I) <0  OR P(I) >100  THEN 401
  40. 391  GOTO 411
  41. 401  PRINT "COME ON, BE REASONABLE!!! TRY AGAIN.": GOTO 381
  42. 411  IF P(I) < > INT(P(I))  THEN 401
  43. 421  IF C5 = 1  THEN 431
  44. 431  VTAB 23: INPUT "WOULD YOU LIKE TO CHANGE ANYTHING?";A$: IF  LEFT$(A$,1) = "Y"  THEN  HOME :C5 = 1: GOTO 241
  45. 441  HOME : NEXT I:C5 = 0: TEXT : HOME : PRINT : IF SC = 10  AND  RND(1) <.25  THEN 701
  46. 451  PRINT "$$ LEMONSVILLE DAILY FINANCIAL REPORT $$": PRINT : POKE 768,152: POKE 769,80: CALL 770: POKE 768,128: POKE 769,160: CALL 770: POKE 768,152: POKE 769,40: CALL 770: POKE 768,144: POKE 769,80: CALL 770: POKE 768,128: POKE 769,200: CALL 770: IF R2 = 2  THEN 691
  47. 461  IF R3 = 3  THEN 711
  48. 471  FOR I = 1 TO N: IF A(I) <0  THEN A(I) = 0
  49. 481  IF R2 = 2  THEN 531
  50. 491  IF P(I) > = P9  THEN 511
  51. 501 N1 = (P9 -P(I))/P9 *.8 *S2 +S2: GOTO 521
  52. 511 N1 = ((P9 ^2) *S2/P(I) ^2)
  53. 521 W =  -S(I) *C9:V = 1 -( EXP(W) *C2):N2 = R1 *(N1 +(N1 *V)):N2 =  INT(N2 *G(I)): IF N2 < = L(I)  THEN 541
  54. 531 N2 = L(I)
  55. 541 M = N2 *P(I) *.01:E = S(I) *S3 +L(I) *C1:P1 = M -E:A(I) = A(I) +P1: IF H(I) = 1  THEN 701
  56. 551  PRINT : IF B(I) < >1  THEN 571
  57. 561  PRINT "STAND ";I;: PRINT "   BANKRUPT": GOSUB 1461: VTAB 5: CALL  -958: GOTO 591
  58. 571  GOSUB 761: IF A(I) >C/100  THEN 591
  59. 581  PRINT "STAND ";I: HOME : PRINT "  ...YOU DON'T HAVE ENOUGH MONEY LEFT": PRINT " TO STAY IN BUSINESS  YOU'RE BANKRUPT!":B(I) = 1: GOSUB 1461: HOME : IF N = 1  AND B(1) = 1  THEN 1511
  60. 591  NEXT I:R1 = 1:R2 = 0: GOTO 121
  61. 601  IF SC = 10  THEN 641
  62. 611  IF SC = 7  THEN 721
  63. 621  IF  RND(1) <.25  THEN 651
  64. 631  GOTO 231
  65. 641 J = 30 + INT( RND(1) *5) *10: PRINT "THERE IS A ";J;"% CHANCE OF LIGHT RAIN,": PRINT "AND THE WEATHER IS COOLER TODAY.":R1 = 1 -J/100:X1 = 1: GOTO 231
  66. 651  PRINT "THE STREET DEPARTMENT IS WORKING TODAY.": PRINT "THERE WILL BE NO TRAFFIC ON YOUR STREET.": IF  RND( -1) <.5  THEN 671
  67. 661 R2 = 2: GOTO 681
  68. 671 R1 = .1
  69. 681 X2 = 1: GOTO 231
  70. 691  PRINT "THE STREET CREWS BOUGHT ALL YOUR": PRINT "LEMONADE AT LUNCHTIME!!": FOR DE = 1 TO 1000: NEXT DE: VTAB 3: CALL  -958: GOTO 471
  71. 701 X3 = 1:R3 = 0:SC = 5: GOSUB 1131: TEXT : HOME : PRINT "WEATHER REPORT:  A SEVERE THUNDERSTORM": PRINT "HIT LEMONSVILLE EARLIER TODAY, JUST AS"
  72. 711  PRINT "THE LEMONADE STANDS WERE BEING SET UP.": PRINT "UNFORTUNATELY, EVERYTHING WAS RUINED!!": FOR J = 1 TO N:G(J) = 0: NEXT : GOTO 471
  73. 721 X4 = 1: PRINT "A HEAT WAVE IS PREDICTED FOR TODAY!":R1 = 2: GOTO 231
  74. 731 STI =  INT(STI *100 +.5)/100:STI$ = "$" + STR$(STI): IF STI =  INT(STI)  THEN STI$ = STI$ +".0"
  75. 741  IF STI =  INT(STI *10 +.5)/10  THEN STI$ = STI$ +"0"
  76. 751  RETURN 
  77. 761  VTAB 6: POKE 34,5: PRINT "   DAY ";D; TAB( 30);"STAND ";I: PRINT : PRINT : PRINT "  ";N2; TAB( 7);"GLASSES SOLD": PRINT :STI = P(I)/100: GOSUB 731: PRINT STI$; TAB( 7);"PER GLASS";:STI = M: GOSUB 731: PRINT  TAB( 27);"INCOME ";STI$: PRINT : PRINT : PRINT "  ";L(I); TAB( 7);"GLASSES MADE": PRINT :STI = E: GOSUB 731: PRINT "  ";S(I); TAB( 7);"SIGNS MADE"; TAB( 25);"EXPENSES ";STI$: PRINT : PRINT 
  78. 771 STI = P1: GOSUB 731: PRINT  TAB( 16);"PROFIT  ";STI$: PRINT :STI = A(I): GOSUB 731: PRINT  TAB( 16);"ASSETS  ";STI$: GOSUB 1461: HOME : RETURN 
  79. 781  POKE 770,173: POKE 771,48: POKE 772,192: POKE 773,136: POKE 774,208: POKE 775,5: POKE 776,206: POKE 777,1: POKE 778,3: POKE 779,240: POKE 780,9: POKE 781,202: POKE 782,208: POKE 783,245: POKE 784,174: POKE 785,0: POKE 786,3: POKE 787,76: POKE 788,2: POKE 789,3: POKE 790,96: POKE 791,0: POKE 792,0
  80. 791 I = K1 = X = Y:K1 = 1:KP = .5:K5 = 5:KB = 25:K2 = 2:K3 = 3:K4 = 4:K5 = 5:K7 = 7:KR = 27:K8 = 8:KT = 13:KL = 14:K6 = 6:K9 = 9: RETURN 
  81. 801  TEXT : HOME : GR : COLOR= 12: FOR I = 0 TO 39: HLIN 0,39 AT I: NEXT : VTAB 2: PRINT ";LLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLL;LLLLL";: PRINT ";LLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLL;LLLLL";: PRINT ";LLLL;;;;L;;;;;L;;;;L;;;;L;;;;L;;;;L;;;;";: PRINT ";LLLL;LL;L;L;L;L;LL;L;LL;LLLL;L;LL;L;LL;";
  82. 811  PRINT ";LLLL;;;;L;L;L;L;LL;L;LL;L;;;;L;LL;L;;;;";: PRINT ";LLLL;LLLL;L;L;L;LL;L;LL;L;LL;L;LL;L;LLL";: PRINT ";;;;L;;;;L;LLL;L;;;;L;LL;L;;;;L;;;;L;;;;";: VTAB 11: PRINT "LLLLLLLL;;;;;LL;LLLLLLLLLLLLLLL;LLLLLLLL";: PRINT "LLLLLLLL;LLLLLL;LLLLLLLLLLLLLLL;LLLLLLLL";
  83. 821  PRINT "LLLLLLLL;LLLLL;;;L;;;;L;;;;L;;;;LLLLLLLL";: PRINT "LLLLLLLL;;;;;LL;LLLLL;L;LL;L;LL;LLLLLLLL";: PRINT "LLLLLLLLLLLL;LL;LL;;;;L;LL;L;LL;LLLLLLLL";: PRINT "LLLLLLLLLLLL;LL;LL;LL;L;LL;L;LL;LLLLLLLL";: PRINT "LLLLLLLL;;;;;LL;LL;;;;L;LL;L;;;;LLLLLLLL";
  84. 831  VTAB 23: PRINT "  COPYRIGHT 1979    APPLE COMPUTER INC.": GOSUB 901: FOR I = 1 TO 2000: NEXT : POKE 33,1: POKE 34,9: POKE 35,19: FOR I = 39 TO 7  STEP  -1: COLOR= 15: VLIN 18,37 AT I: COLOR= 12: IF I <39  THEN  VLIN 18,36 AT I +1
  85. 841  COLOR= 15: IF I <30  THEN  VLIN 18,36 AT I +10
  86. 851  COLOR= 12: IF I <29  THEN  VLIN 18,37 AT I +11: POKE 32,I +11: VTAB 11: HTAB I +12: PRINT : READ A$: PRINT A$;
  87. 861  FOR J = 14 TO I +I: NEXT : NEXT : FOR I = 1 TO 1000: NEXT : COLOR= 13: VLIN 14,36 AT 12: FOR I = 36 TO 20  STEP  -1: HLIN 8,16 AT I: FOR J = 1 TO 50: NEXT : POKE 768,I *3 -12: POKE 769,12: CALL 770: NEXT : COLOR= 12: VLIN 14,19 AT 12: POKE 32,0: POKE 33,40: POKE 34,20: POKE 35,23: VTAB 22: FOR I = 1 TO 4000: NEXT :I =  FRE(0): RETURN 
  88. 871  DATA  96,180,128,60,114,60,128,120,144,60,152,60,128,255,128,60,114,60,85,120,96,60,102,60,114,120,102,60,96,255,0,0, ,,,,,,L;LL;,L;LL;,;;LL;;,L;LL;,L;;;;,,,;L;;;;,;L;LL;,;L;LL;,;L;LL;,;;;LL;,,,,,*, 96,16,85,4,128,4,96,4,76,4,128,4,96,16,0,0
  89. 881  DATA  114,120,144,60,114,255,1,120,128,120,144,60,128,120,114,60,144,120,171,255,228,255,0,0, 152,180,152,120,152,60,144,120,152,60,171,120,192,60,152,255,0,0
  90. 891  DATA  0,160,128,255,152,40,171,80,192,40,228,255,1,40,0,160,192,255,192,40,171,80,152,40,128,255,0,0
  91. 901  READ I,J: IF J = 0  THEN  RETURN 
  92. 911  POKE 768,I: POKE 769,J: CALL 770: GOTO 901
  93. 921  TEXT : HOME : PRINT "HI!  WELCOME TO LEMONSVILLE, CALIFORNIA!": PRINT : FOR I = 1 TO 10:J =  RND(1) *25 +50: POKE 768,J: POKE 769,10: CALL 770: NEXT : PRINT "IN THIS SMALL TOWN, YOU ARE IN CHARGE OF": PRINT "RUNNING YOUR OWN LEMONADE STAND. YOU CAN": PRINT "COMPETE WITH AS MANY OTHER PEOPLE AS YOU"
  94. 931  PRINT "WISH, BUT HOW MUCH PROFIT YOU MAKE IS UP": PRINT "TO YOU (THE OTHER STANDS' SALES WILL NOT": PRINT "AFFECT YOUR BUSINESS IN ANY WAY). IF YOU": PRINT "MAKE THE MOST MONEY, YOU'RE THE WINNER!!": PRINT : PRINT "ARE YOU STARTING A NEW GAME? (YES OR NO)"
  95. 941  VTAB 21: CALL  -958: INPUT "(PLEASE TYPE Y OR N AND PRESS RETURN)";A$:A$ =  LEFT$(A$,1): IF A$ < >"Y"  AND A$ < >"N"  THEN  PRINT  CHR$(7);: GOTO 941
  96. 951  VTAB 23: CALL  -958: INPUT "HOW MANY PEOPLE WILL BE PLAYING ==> ";N$:N =  VAL(N$): IF N <1  OR N >30  THEN  PRINT  CHR$(7);: GOTO 951
  97. 961  RETURN 
  98. 971  HOME : PRINT "TO MANAGE YOUR LEMONADE STAND, YOU WILL ": PRINT "NEED TO MAKE THESE DECISIONS EVERY DAY: ": PRINT : PRINT "1. HOW MANY GLASSES OF LEMONADE TO MAKE    (ONLY ONE BATCH IS MADE EACH MORNING)"
  99. 981  PRINT "2. HOW MANY ADVERTISING SIGNS TO MAKE      (THE SIGNS COST FIFTEEN CENTS EACH)  ": PRINT "3. WHAT PRICE TO CHARGE FOR EACH GLASS  ": PRINT : PRINT "YOU WILL BEGIN WITH $2.00 CASH (ASSETS).": PRINT "BECAUSE YOUR MOTHER GAVE YOU SOME SUGAR,"
  100. 991  PRINT "YOUR COST TO MAKE LEMONADE IS TWO CENTS ": PRINT "A GLASS (THIS MAY CHANGE IN THE FUTURE).": PRINT : GOSUB 1461: HOME : PRINT "YOUR EXPENSES ARE THE SUM OF THE COST OF": PRINT "THE LEMONADE AND THE COST OF THE SIGNS. ": PRINT : PRINT "YOUR PROFITS ARE THE DIFFERENCE BETWEEN "
  101. 1001  PRINT "THE INCOME FROM SALES AND YOUR EXPENSES.": PRINT : PRINT "THE NUMBER OF GLASSES YOU SELL EACH DAY ": PRINT "DEPENDS ON THE PRICE YOU CHARGE, AND ON ": PRINT "THE NUMBER OF ADVERTISING SIGNS YOU USE.": PRINT : PRINT "KEEP TRACK OF YOUR ASSETS, BECAUSE YOU  "
  102. 1011  PRINT "CAN'T SPEND MORE MONEY THAN YOU HAVE!   ": PRINT : GOSUB 1461: HOME : RETURN 
  103. 1021  CALL  -936: PRINT  CHR$(7);:I = 0: PRINT "HI AGAIN!  WELCOME BACK TO LEMONSVILLE! ": PRINT : PRINT "LET'S CONTINUE YOUR LAST GAME FROM WHERE": PRINT "YOU LEFT IT LAST TIME.  DO YOU REMEMBER ": PRINT "WHAT DAY NUMBER IT WAS? ";
  104. 1031  INPUT "";A$:A =  VAL(A$): PRINT : IF A < >0  THEN 1071
  105. 1041 A$ =  LEFT$(A$,1): IF A$ = "Y"  THEN  PRINT "GOOD!  WHAT DAY WAS IT? ";:I = I +1: GOTO 1031
  106. 1051  IF A$ = "N"  OR I >0  THEN 1091
  107. 1061  PRINT  CHR$(7);"YES OR NO? ";:I = I +1: GOTO 1031
  108. 1071  IF A <1  OR A >99  OR A < > INT(A)  THEN 1091
  109. 1081 D = A
  110. 1091  PRINT "OKAY - WE'LL START WITH DAY NO. ";D +1: PRINT : FOR I = 1 TO N: PRINT : PRINT : PRINT "PLAYER NO. ";I;", HOW MUCH MONEY (ASSETS)": PRINT : PRINT "DID YOU HAVE? ";: INPUT "";A$:A =  VAL(A$): PRINT : IF A <2  THEN  PRINT "O.K. - <CTRL-A>E'LL START YOU OUT WITH $2.00":A = 2: GOTO 1111
  111. 1101  IF A >40  THEN  PRINT "JUST TO BE FAIR, LET'S MAKE THAT $10.00":A = 10
  112. 1111 A(I) =  INT(A *100 +.5)/100: NEXT : PRINT : PRINT  CHR$(7): INPUT "...READY TO BEGIN? ";A$: IF  LEFT$(A$,1) = "N"  THEN 971
  113. 1121  RETURN 
  114. 1131  GR : HOME : COLOR= SC: FOR I = 0 TO 25: HLIN 0,39 AT I: NEXT I: COLOR= 12: IF SC = 5  THEN  COLOR= 4
  115. 1141  FOR I = 26 TO 39: HLIN 0,39 AT I: NEXT I: COLOR= 8: FOR I = 24 TO 32: HLIN 15,25 AT I: NEXT I: HLIN 15,25 AT 14: VLIN 14,23 AT 15: VLIN 14,23 AT 25: COLOR= 13: FOR I = 17 TO 23  STEP 2: VLIN 22,23 AT I: NEXT I: IF SC = 2  OR SC = 7  THEN 1191
  116. 1151  IF SC = 10  THEN  COLOR= 15
  117. 1161  IF SC = 5  THEN  COLOR= 0
  118. 1171  HLIN 6,10 AT 2: HLIN 4,14 AT 3: HLIN 7,12 AT 4: HLIN 22,30 AT 4: HLIN 20,36 AT 5: HLIN 23,33 AT 6: IF SC = 5  THEN  GOSUB 1451
  119. 1181  GOTO 1211
  120. 1191  IF SC = 7  THEN  COLOR= 9
  121. 1201  HLIN 3,5 AT 1: HLIN 2,6 AT 2: FOR I = 3 TO 6: HLIN 1,7 AT I: NEXT : HLIN 2,6 AT 7: HLIN 3,5 AT 8
  122. 1211  VTAB 22: HTAB 8: PRINT " LEMONSVILLE WEATHER REPORT ": PRINT : VTAB 22: HTAB 8: PRINT " LEMONSVILLE WEATHER REPORT ": PRINT : IF SC = 2  THEN  HTAB 18: PRINT " SUNNY ";
  123. 1221  IF SC = 7  THEN  HTAB 15: PRINT " HOT AND DRY ";
  124. 1231  IF SC = 10  THEN  HTAB 17: PRINT " CLOUDY ";
  125. 1241  IF SC = 5  THEN  HTAB 14: PRINT " THUNDERSTORMS! ";: GOSUB 1451
  126. 1251  RESTORE 
  127. 1261  READ A$: IF A$ < >"*"  THEN 1261
  128. 1271  IF SC < >2  THEN 1301
  129. 1281  READ I,J: IF J = 0  THEN 1381
  130. 1291  FOR K = 1 TO J: POKE 768,I: POKE 769,10: CALL 770: FOR L = K TO J: NEXT : NEXT : GOTO 1281
  131. 1301  READ I,J: IF J < >0  THEN 1301
  132. 1311  IF SC = 7  THEN 1351
  133. 1321  READ I,J: IF J < >0  THEN 1321
  134. 1331  IF SC = 10  THEN 1351
  135. 1341  READ I,J: IF J < >0  THEN 1341
  136. 1351  READ I,J: IF J = 0  THEN 1381
  137. 1361  IF I = 1  THEN  FOR I = 1 TO J: NEXT : GOTO 1351
  138. 1371  POKE 768,I: POKE 769,J: CALL 770: GOTO 1351
  139. 1381  IF SC = 5  THEN  GOSUB 1451
  140. 1391 I =  FRE(0): FOR I = 1 TO 2000: NEXT : RETURN 
  141. 1401  POKE 800,76: POKE 801,140: POKE 802,3: POKE 803,165: POKE 804,48: POKE 805,41: POKE 806,15: POKE 807,141: POKE 808,192: POKE 809,3: POKE 810,165: POKE 811,48: POKE 812,41: POKE 813,240: POKE 814,141: POKE 815,193: POKE 816,3: POKE 817,165: POKE 818,36: POKE 819,141: POKE 820,194: POKE 821,3: POKE 822,165: POKE 823,37: POKE 824,141: POKE 825,195
  142. 1411  POKE 826,3: POKE 827,169: POKE 828,0: POKE 829,133: POKE 830,36: POKE 831,133: POKE 832,37: POKE 833,72: POKE 834,32: POKE 835,193: POKE 836,251: POKE 837,133: POKE 838,40: POKE 839,164: POKE 840,36: POKE 841,177: POKE 842,40: POKE 843,41: POKE 844,15: POKE 845,205: POKE 846,196: POKE 847,3: POKE 848,208: POKE 849,10: POKE 850,177: POKE 851,40
  143. 1421  POKE 852,41: POKE 853,240: POKE 854,24: POKE 855,109: POKE 856,192: POKE 857,3: POKE 858,145: POKE 859,40: POKE 860,177: POKE 861,40: POKE 862,41: POKE 863,240: POKE 864,205: POKE 865,197: POKE 866,3: POKE 867,208: POKE 868,10: POKE 869,177: POKE 870,40: POKE 871,41: POKE 872,15: POKE 873,24: POKE 874,109: POKE 875,193: POKE 876,3: POKE 877,145
  144. 1431  POKE 878,40: POKE 879,200: POKE 880,192: POKE 881,40: POKE 882,144: POKE 883,213: POKE 884,160: POKE 885,0: POKE 886,104: POKE 887,105: POKE 888,0: POKE 889,197: POKE 890,34: POKE 891,144: POKE 892,196: POKE 893,32: POKE 894,193: POKE 895,251: POKE 896,133: POKE 897,40: POKE 898,173: POKE 899,162: POKE 900,48: POKE 901,133: POKE 902,36: POKE 903,173
  145. 1441  POKE 904,195: POKE 905,3: POKE 906,133: POKE 907,37: POKE 908,165: POKE 909,48: POKE 910,41: POKE 911,15: POKE 912,141: POKE 913,196: POKE 914,3: POKE 915,165: POKE 916,48: POKE 917,41: POKE 918,240: POKE 919,141: POKE 920,197: POKE 921,3: POKE 922,96: RETURN 
  146. 1451  GOSUB 1401: FOR LIGHTNING = 1 TO 2: GOSUB 11: FOR RPT = 1 TO 5: COLOR= 4: CALL 800: COLOR= 12: CALL 803: COLOR= 15: CALL 800: COLOR= 9: CALL 803: COLOR= 15: CALL 803: COLOR= 12: CALL 800: COLOR= 4: CALL 803: NEXT : COLOR= 15: CALL 800: COLOR= 5: CALL 803: NEXT : RETURN 
  147. 1461  VTAB 24: PRINT "PRESS RETURN TO CONTINUE, ESC TO END...";: POKE  -16368,0
  148. 1471  GET IN$: IF  ASC(IN$) < >13  AND  ASC(IN$) < >27  THEN 1471
  149. 1481  IF  ASC(IN$) < >27  THEN  RETURN 
  150. 1491  HOME : VTAB 8: PRINT "ARE YOU SURE YOU WANT TO QUIT ?";: GET IN$: IF IN$ = "Y"  THEN 1511
  151. 1501  RETURN 
  152. 1511  TEXT : HOME : PRINT  CHR$(4),"-/BLANK0.J/menu": NEW